1000 A=100:GOTO 20:REM PROGRAMMVERZEICHNIS KASSETTE
1010 DIM NA$(20),ZN$(20),I$(20)
1020 RESTORE :GOSUB 100:READ NR$
1030 IF LEN(NR$)<>3 THEN NR$="   "
1040 SR$=" PROGRAMMVERZEICHNIS KASSETTE "+NR$
1050 GOSUB 150:VE=1:HO=0:GOSUB 110
1060 PRINT "  Folgende Programme sind gespeichert :"
1070 FOR I=1 TO 20
1080 READ NA$(I),ZN$(I),I$(I)
1090 IF LEN(ZN$(I))=0 THEN ZN$(I)="---"
1100 IF LEN(ZN$(I))=1 THEN ZN$(I)="00"+ZN$(I)
1110 IF LEN(ZN$(I))=2 THEN ZN$(I)="0"+ZN$(I)
1120 IF LEN(ZN$(I))>3 THEN ZN$(I)="***"
1130 IF LEN(NA$(I))>20 THEN NA$(I)="FEHLER!  zu lang !!"
1140 IF LEN(I$(I))>35 THEN I$(I)="FEHLER! Info ist zu lang"
1150 SR=I:GOSUB 300
1160 IF LEN(SR$)=1 THEN SR$="0"+SR$
1170 D$=SR$+" "+NA$(I):REM   SR$=D$
1180 U=LEN(D$):U$=".":U1=24-U
1190 FOR K=1 TO U1:UU$=UU$+U$:NEXT K
1200 SR$=D$+UU$:GOSUB 150
1210 PRINT "ZW-Nr";ZN$(I)
1220 UU$=""
1230 NEXT I
1240 VE=22:HO=2:GOSUB 110
1250 INPUT "Bitte Programmnummer eingeben :";PN$
1260 IF (PN$<"01")OR(PN$>"20")THEN 1240
1270 PN=VAL(PN$)
1280 FOR I=1 TO 20
1290 IF PN=I THEN GOSUB 1400
1300 NEXT I
1310 GOSUB 100
1320 VE=10:HO=2:GOSUB 110
1330 PRINT "Weiter suchen ? (j/n)"
1340 HO=23:GOSUB 110:GOSUB 210
1350 IF IN=74 THEN 1020
1360 IF IN=78 THEN 950
1370 GOTO 1320
1380 REM  DARSTELLUNG TITEL & INFO
1390 REM ********************************
1400 GOSUB 100:
1410 SR$="PROGRAMMTITEL  : "+NA$(I)
1420 GOSUB 150:VE=2:HO=0:GOSUB 110
1430 SR$="Zaehlwerknummer: "+ZN$(I)+"        "
1440 GOSUB 150:VE=6:HO=2:GOSUB 110
1450 PRINT "KURZINFORMATION ZUM PROGRAMM"
1460 VE=7:GOSUB 110:PRINT "============================"
1470 IF LEN(I$(I))<1 THEN I$(I)="KEINE INFORMATION VORHANDEN"
1480 VE=9:HO=2:GOSUB 110:PRINT I$(I)
1490 VE=21:HO=15:GOSUB 110
1500 PRINT "Weiter --> eine Taste";:GOSUB 210
1510 RETURN
25000 REM  ***   DATA ZEILEN   ***
25010 REM *****************************
25020 DATA "1/A"
25030 DATA "1. Programm","1","info 1"
25040 DATA "2. Programm","20","info 2"
25050 DATA "3. Programm","30","info 3"
25060 DATA "4. Programm","40","info 4"
25070 DATA "5. Programm","50","info 5"
25080 DATA "","",""
25090 DATA "","",""
25100 DATA "","",""
25110 DATA "","",""
25120 DATA "","",""
25130 DATA "","",""
25140 DATA "","",""
25150 DATA "","",""
25160 DATA "","",""
25170 DATA "","",""
25180 DATA "","",""
25190 DATA "","",""
25200 DATA "","",""
25210 DATA "","",""
25220 DATA "","",""
30000 REM ______________________________
30010 REM INFORMATIONEN ZUR BELEGUNG
30020 REM DER DATAZEILEN
30030 REM ______________________________
30040 REM MAXIMALE ZEICHENLAENGEN
30050 REM - PROGRAMMNAME(NA$)20 ZEICHEN
30060 REM - ZAEHLWERKNR.(ZN$) 3 ZEICHEN
30070 REM - KASSETTENNR.(NR$)=3 ZEICHEN
30080 REM - INFO'S      (I$) 35 ZEICHEN
30090 REM SOLLTE DOCH EINMAL EINE ZEI-
30100 REM CHENKETTE ZU LANG WERDEN,SO
30110 REM WIRD BEI DER WIEDERGABE EINE
30120 REM FEHLERMELDUNG GEGEBEN. BEI
30130 REM DER ZAEHLWERKNUMMER ERSCHEINT
30140 REM ALS FEHLERMELDUNG EIN "***".
30150 REM 
30160 REM DIE DATAZEILEN SIND IM VOR-
30170 REM LIEGENDEN PROGRAMM MIT EINER
30180 REM DEMONSTRATION BELEGT.
30190 REM 
30200 REM - KASSETTENNUMMER UND SEITE
30210 REM   IN ZEILE 25020 EINTRAGEN !
30220 REM ______________________________
32000 REM *****************************
32010 REM *                           *
32020 REM *   PROGRAMM ERSTELLT VON   *
32030 REM *   BURKHARDT PREUSS        *
32040 REM *   H.-BEIMLER-STR.20       *
32050 REM *   FRANKFURT/O. 1200       *
32060 REM *   AUF EINEM C 64          *
32070 REM *   AM 18.09.89             *
32080 REM *   LETZTE MODIFIKATION     *
32090 REM *   AM 05.10.89             *
32100 REM *                           *
32110 REM *****************************
32120 REM 
32130 REM Erstausstrahlung: Radio DDR
32140 REM 900110