.Z80
	.PHASE	0200H
;***************************************
; CENTRONIC- TREIBER f]r M021
;***************************************
;VEREINBARUNGEN:
CAOS    EQU     0F003H
HCOP    EQU     0B799H  ;HARDCOPY
CRT     EQU     0       ;UP-NR. CRT
;SYSTEMZELLEN CAOS
;
MKENN   EQU     0EFH    ;MODULKENNBYTE
PIOA    EQU     90H     ;PIO KANAL A DAT
PIOAC   EQU     92H     ;    STEUERWORT
PIOB    EQU     91H     ;PIO B DATEN
PIOBC   EQU     93H     ;    STEUERWORT
;
;**************************************
        JR      START   ;SELBSTSTARTADR.
	JR	SDD
;---------------------------------------
;
START:	LD	A,0FFH		;Init. Port A
	OUT	(PIOBC),A
	XOR	A
	OUT	(PIOBC),A
	;
	LD      A,0FFH		;Init Port B
	OUT	(PIOAC),A
	LD	A,080H
        OUT     (PIOAC),A
	LD	A,080H
	OUT	(PIOB),A
	;
	LD	HL,INI
	LD	B,INIE-INI
	CALL	INBIM
	LD	HL,BIMOD
	LD	(HCOP),HL
	RET
	;
	;
INBIM:	PUSH	BC
	LD	BC,150
INBI0:	PUSH	BC
	IN	A,(PIOA)
	BIT	6,A
	JR	Z,INBI1
	LD	A,2
	CALL	CAOS
	DEFB	14H
	POP	BC
	DEC	BC
	LD	A,B
	OR	C
	JR	NZ,INBI0	
	CALL	CAOS
	DEFB	23H
	DEFB	0AH
	DEFB	0DH
Š	DEFB	'PRINTER NOT READY'
	DEFB	0AH
	DEFB	0DH
	DEFB	0
	POP	BC
	RET
INBI1:	POP	BC
	POP	BC
INBI2:	LD	A,(HL)
	INC	HL
	CALL	SDD
	DJNZ	INBI2
	RET
;
;***************************************
; ZEICHENAUSGABE (ZEICHEN IN A)
; DIREKTE BYTEAUSGABE
SDD:    PUSH    BC      ;AUSGABE DATEN
        PUSH    AF
SDA:    IN      A,(PIOA)
        BIT     6,A
        JR      Z,SDB   ;BUSY?
        LD      A,2
        CALL    CAOS
        DEFB    14H     ;WARTEN
        JR      SDA
;
SDB:    POP     AF
	PUSH	AF
        OUT     (PIOB),A  ;DATEN
	XOR	A
	OUT	(PIOA),A
	LD      A,080H
	OUT	(PIOA),A
	POP	AF
	POP	BC
	RET
;
;***	Initialisierungstabellen   *********
;
;	Druckertyp: OKI ML 182 Elite
;
;	Printermode
;
INI:	DEFB	01BH	;Steuercode
	DEFB	030H	;Draftquality
	DEFB	01BH	;Steuercode
	DEFB	021H	;Zeichensatz
	DEFB	043H	;Deutsch
	DEFB	0AH	;1* Blattvorschub
	DEFB	0DH
INIE	EQU	$
;
;	Grafikmode
;
INTAB2:	DEFB	0DH
	DEFB	09H
	DEFB	1BH
	DEFB	'J'
	DEFB	24
	DEFB	1BH
Š	DEFB	2AH
	DEFB	5
	DEFB	40H
	DEFB	1
INTABE	EQU	$
;
BIMOD:	PUSH	HL
	PUSH	DE
	PUSH	AF
	PUSH	BC
	LD	H,0
BIM1:	PUSH	HL
	LD	HL,INTAB2
	LD	B,INTABE-INTAB2
	CALL	INBIM
	POP	HL
	LD	L,0
BIM4:	LD	B,8
	PUSH	HL
	LD	DE,0B700H
BIM2:	PUSH	HL
	PUSH	DE
	CALL	0F003H
	DEFB	34H
	LD	A,(HL)
	POP	DE
	LD	(DE),A
	INC	DE
	POP	HL
	INC	H
	DJNZ	BIM2 			
	LD	C,8
BIM5:	LD	B,8
	LD	HL,0B700H
BIM3:	RL	(HL)
	RLA
	INC	HL
	DJNZ	BIM3	
	CALL	SDD
	DEC	C
	JR	NZ,BIM5
	POP	HL
	INC	L
	LD	A,40
	CP	L
	JR	NZ,BIM4
	LD	A,(IX+13)
	CP	13H
	JR	Z,BIM6
	LD	A,H
	ADD	A,8
	LD	H,A
	JR	NC,BIM1
BIM6:	LD	A,0AH
	CALL	SDD 
	LD	A,0DH
	CALL	SDD
	POP	BC
	POP	AF
	POP	DE
	POP	HL
Š	RET
	.DEPHASE
	END