;CENTRONICSTREIBER f. KC 85 - Floppy mit M 021 Joystick/Centronics
;30.06.1990 / Menge
;Copyright DACOTEK GMBH 
;
;*************************************************
;
        .Z80
	.PHASE	0BA00H
;VEREINBARUNGEN:
;
CAOS	EQU	0F003H		;PV 1
HCADR	EQU	0B799H		;HARDCOPYADR
;
PIOA	EQU	090H		;DATENWORT  A
PIOAC	EQU	092H		;STEUERWORT A
PIOB	EQU	091H		;DATENWORT  B
PIOBC	EQU	093H		;STEUERWORT B
;
INIT:	JR	START	;AUFRUF INITIALISIERUNG
OUTLST:	JR	SD1	;BYTEAUSGABE
;
;****** BLINDPARAMETER FUER INSTALLATION MIT MSYSg
;
	DEFW	0
	DEFW	0
	DEFW 	0
	DEFW	0
;	
;****** INIT PIO
;
START:	LD	HL,BIMOD		; HC-Adr. setzen 
	LD	(HCADR),HL
;	ld	de,sd1
;	ld	hl,out1
;	ld 	(hl),e
;	ind	hl
;	ld	(hl),d
	LD	A,0FFH
	OUT	(PIOAC),A	        ; Bit Mode
        LD	A,040H
        OUT     (PIOAC),A               ; Bit 6 = BUSY
	;
	LD	A,0FFH     
        OUT     (PIOBC),A               ; Bit Mode
	XOR	A
        OUT     (PIOBC),A               ; Alle Bits Out
        LD 	A,080H 
        OUT     (PIOA),A                ; Strobe Passiv
	RET
;
;****** ZEICHENAUSGABE MIT ZEICHEN IN A
;
SD1:	PUSH	BC		; Ausgabe Daten
        PUSH    AF
	;
SDA:	IN	A,(PIOA)
	BIT	6,A
	JR	Z,SDB        	 ; BUSY = 0 ?
	LD	A,5
        CALL	CAOS
        DEFB    14H 	         ; Wait 5 x 6 MS
        JR      SDA
;	
SDB:    POP     AF
        PUSH    AF
        OUT     (PIOB),A 	 ; Daten
        XOR	A
        OUT     (PIOA),A         ; Strobe
        LD	A,080H
        OUT     (PIOA),A         ; Impuls
        POP	AF
        POP     BC
BIMOD:  RET
	DEFW	07F7FH
	DEFM	'CENT'
	DEFB	01
	JP	START
;	
;***************************************
	DEFM	'28.05.90_egneM/ C DACOTEK'
	.DEPHASE
	END
;