subttl	out80 
	.PRINTX	'BILDSCHIRMAUSGABE'
;Bildschirmausgabe fuer KC mit 80 Zeichen/Seite
; und ESCAPE-Sequenzen
; K.-D. Kirves
; 23.11.87
;************************************************
;
BST2	EQU	BST1+180H
PADRE	EQU	34H
CAOS1	EQU	0F009H
ARGN	EQU	0B781H
ARG1	EQU	ARGN+1
ARG2	EQU	ARG1+2
ARG3	EQU	ARG2+2
ARG4	EQU	ARG3+2
CURSO	EQU	0B7A0H
WINNR	EQU	0B79BH
WINON	EQU	0B79CH
WINLG	EQU	0B79EH
STBT	EQU	CURSO+2
COLOR	EQU	0B7A3H
UOUT1	EQU	0B7BDH
UIN1	EQU	UOUT1+3
UOUT2	EQU	UIN1+3
UIN2	EQU	UOUT2+3
HOR	EQU	0B7D3H
VERT	EQU	0B7D5H
PCOLOR	EQU	0B7D6H
ESC	EQU	1BH
BSSTIN	EQU	0B6F3H
;Programmanfang
out80:	push	hl
	push	de
	push	bc
	ld	bc,pops
	push	bc
	ld	b,a
	ld	a,(escmer)
	and	a
	jr	nz,escp
	ld	a,b
	CP	82H
	RET	Z		;CURSOR EIN
	CP	83H
	RET	Z		;CURSOR	OF
	CP	1BH
Š	JR	Z,ESCAPE
	ld	a,(bsmod)
	and	a
	ld	a,b
	jp	z,char80
SYSOUT:	CP	14H
	JR	Z,CES
	CP	15H
	JR	Z,CEL
	CP	7FH
	JR	NZ,OUT
	LD	A,1FH
OUT:	CALL	CAOS		;CAOS-MODE
	DEFB	0		;40 ZCHN.BS
	RET
;LOESCHEN BIS ZEILENENDE
CELP:	LD	A,(CURSO)
	PUSH	AF
	LD	B,A
	LD	A,(WINLG)
	INC	A
	SUB	B
	LD	B,A
	LD	A,11H
	CALL	CAOS
	DEFB	0
CELP1:	LD	A,' '
	CALL	OUT
	DJNZ	CELP1
	LD	A,12H
	CALL	CAOS
	DEFB	0
Š	POP	AF
	JP	ESCB1
;LOESCHEN BIS BILDSCHIRMENDE
CESP:	CALL	CELP
	LD	A,(CURSO+1)
	INC	A
	PUSH	AF
	LD	B,A
	LD	A,(WINLG+1)
	INC	A
	SUB	B
	RET	Z
	LD	B,A
	POP	AF
	PUSH	AF
CES1:	LD	(CURSO+1),A
	LD	A,2
	CALL	OUT
	LD	A,(CURSO+1)
	INC	A
	DJNZ	CES1
	POP	AF
	DEC	A
	LD	B,A
	JP	CR8
;Rueckkehrsammeladresse
pops:	XOR	A		;CY=0
POPS1:	pop	bc
	pop	de
	pop	hl
	ret
;
escape:	ld	a,80h
	ld	(escmer),a
	ret
;
escp:	bit	7,a
	jr	nz,esca		;esc-neu
	bit	6,a
	jr	nz,escb		;locate 2
	ld	hl,(pzeig)	;Parametererfassung
	ld	(hl),b
	inc	hl
	ld	(pzeig),hl
	ld	a,(escmer)
	dec	a
	ld	(escmer),a	;Anzahl
	ret	nz
	ld	hl,(escad)	;Adresse
jpesc:	push	hl
	ld	hl,ppuf
	ld	(pzeig),hl
	ld	a,m
	ret
;		
esca:	ld	a,b
	cp	7fh
	jr	c,esc1
	ld	a,40h
	ld	(escmer),a
	ld	a,b
	and	1fh
	ld	(curso+1),a
	ret
;
escb:	xor	a
Š	ld	(escmer),a
	ld	a,b
	and	7fh
ESCB1:	ld	(curso),a
	ret
;
ESC1:	SUB	41H
	jr	C,escend
	LD	C,A
	LD	B,0
	LD	HL,ESCTAB
	ADD	HL,BC
	ADD	HL,BC
	add	hl,bc		;*3
	LD	a,(HL)
	INC	HL
	ld	b,(hl)
	inc	hl
	LD	H,(HL)
	LD	L,b
	and	a
	ld	(escmer),a	;anzahl parameter
	jr	z,jpesc
	ld	(escad),hl
ret:	ret
;
escend:	xor	a
ESCEN1:	ld	(escmer),a
	ret

;FUNKTIONEN
;A=PUNKTSETZEN
PSET:	LD	E,30H
	DEFB	01H
;B=PUNKTRUECKSETZEN
PRES:	LD	E,2FH
	LD	B,3
	PUSH	DE
	LD	DE,HOR
	LD	BC,3
	LDIR
	POP	DE
CALLPV:	jp	CAOS1
;C=GRAFIKFARBE
GFARB:	AND	1FH
	RLCA
	RLCA
	RLCA
	LD	(PCOLOR),A
	RET
;D=LINIE
LINE:	LD	DE,ARG1
	LD	BC,3
	LDIR
	XOR	A
	LD	(DE),A
	INC	DE
	LD	C,3
	LDIR
	LD	(DE),A
	LD	E,3EH
	JR	CALLPV
;E=KREIS
CIRCL:	LD	DE,ARG1
	LD	BC,3
	LDIR
	XOR	A
	LD	(DE),A
	INC	DE
	LDI
	LD	(DE),A
	LD	E,3FH
	JR	CALLPV
Š;F=FENSTERAUFRUF
WINDOW:	CP	10H
	RET	NC
	LD	E,3DH
	JR	CALLPV
;G=SOUND
SOUND:	LD	DE,ARG1
	LD	BC,6
	LDIR
	LD	E,35H
	JR	CALLPV
;H=FARBE
COLORZ:	AND	1FH
	RLCA
	RLCA
	RLCA
	INC	HL
	LD	B,A
	LD	A,(HL)
	AND	7
	OR	B
	LD	(COLOR),A
	RET

;L=FENSTEREINRICHTEN
WININ:	INC	HL
	LD	C,(HL)
	INC	HL
	LD	B,(HL)
	INC	HL
	LD	E,(HL)
	INC	HL
	LD	D,(HL)
	LD	L,C
	LD	H,B
	CALL	0F003H
	DEFB	3ch
	RET
;M=LOESCHEN GRAFIK
CLS8:	LD	A,(COLOR)
	LD	D,0
;	CALL	INK2
CLSG:	LD	HL,8000H
	LD	DE,8001H
	LD	BC,27FFH
	LD	(HL),L
	LDIR
	RET
;N=WECHSEL VORDERGRUND KOMPLETT
INK:   	AND	1FH
	RLCA
	RLCA
	RLCA
	LD	D,7
INK2:	LD	E,A
	LD	A,(COLOR)
	AND	D
	OR	E
	LD	(COLOR),A
Š	LD	A,(KC4)
	LD	HL,0A800H
	LD	BC,0A00H
	AND	A
	JR	Z,INK1
	LD	A,(IX-32)
	SET	1,A
	OUT	(84H),A		;LATCH 08
	LD	HL,8000H
	LD	BC,2800H
INK1:	LD	A,(HL)
	AND	D
	OR	E
	LD	(HL),A
	INC	HL
	DEC	BC
	LD	A,C
	OR	B
	JR	NZ,INK1
	LD	A,(IX-32)
	OUT	(84H),A
	RET
;O=WECHSEL HINTERGRUND KOMPLETT
BACK:	AND	7
	LD	D,0F8H
	JR	INK2
;P=UMSCHALTUNG BS-MODE
BSMODE:	LD	A,(CURMER)
	AND	A
	XOR	A
	LD	(CURMER),A
	CALL	NZ,CUCPL
	ld	a,(bsmod)
	xor	1
	ld	(bsmod),a
	CALL	page
	LD	L,1
STATS:	LD	BC,BSSTIN
	IN	A,(C)
	XOR	L
	OUT	(C),A	
	RET
;Q=lesen 1Byte 
read1:	inc	hl
	ld	h,(hl)
	ld	l,a
	ld	bc,SIDE2+100H	;koppelpuffer
	outi
read2:	xor	a
	ld	bc,0AEF3H	;MEMANF
	out	(C),a
	ret
;R=lesen 256 Byte
readn:	inc	hl
	ld	h,(hl)
	ld	l,a
	LD	E,0
	ld	bc,SIDE2+100H
READ3:	OUTI
	INC	B
	INC	B
	DEC	E
	JR	NZ,READ3	
	jr	read2
;S=SCHREIBT EIN BYTE
ŠWRITE1:	LD	E,(HL)
	INC	HL
	LD	D,(HL)
	INC	HL
	LDI
	RET
;T=schreiben NN bytes
writen:	ld	hl,(ppuf)
	LD	A,(PPUF+4)
	ld	(hl),a
	inc	hl
	ld	(ppuf),hl
	ld	hl,(ppuf+2)
	dec	hl
	ld	(ppuf+2),hl
	ld	a,l
	or	h
	ret	z
	ld	hl,ppuf+4
	ld	(pzeig),hl
	ld	a,1
	JP	ESCEN1
;U=AUFRUF UNTERPROGRAMM
GOSUB:	inc	hl
	LD	H,(HL)
	LD	L,A
	JP	(HL)
;V=AUFRUF CAOS-BILDSCHIRMROUTINE
CAOSBS:	LD	E,24H
CALLP1:	JP	CAOS1
;W=AUSGABE UEBER USER2
USOUT2:	LD	E,2
	JR	CALLP1
;X=ausgabe }ber user3
usout3:	ld	e,3
	jr	callp1	
;Y=EINGABE UEBER USERIN2
USIN2:	ret	
;Z=NICHT BESETZT
;5BH=AUFRUF CAOS-SPRUNGVERTEILER
CAOSPV:	LD	E,A
	JR	CALLP1
;5CH=RUECKKEHR IN'S CAOS
EXIT:	JP	0E000H		;CAOS-WARMSTART
;5dH= wechsel Zeichensatz
zsatz:	ld	hl,zw1
	ld	de,gum
	ld	b,24
	call	zwu
	ld	hl,zw2
	ld	b,32
	CALL	ZWU
	LD	L,2
STATS1:	JP	STATS
;
zwu:	ld	a,(DE)
	ldi
	dec	hl
Š	inc	bc
	ld	(HL),a
	inc	hl
	djnz	zwu
	RET
;
scrmod:	ld	a,(scmode) 
	xor	1
	ld	(scmode),a
	LD	L,8
	CALL	STATS
	ld	a,11h
	jr	z,sm1		;-> scroll
	ld	hl,page
sm2:	ld	(scend),hl
	jr	caosbs
;
sm1:	ld	hl,scroll
	inc	a
	jr	sm2
;  KEYBORDMODE-Wechsel
kbdmod:	di
	ld	hl,ktab
	ld	b,192	;laenge
key1:	ld	a,m
	cp	'A'
	jr	c,key2
	cp	'Z'+1
	jr	nc,key3
	set	5,m
	jr	key2
;
key3:	cp	'a'
	jr	c,key2
	cp	'z'+1
	jr	nc,key2
	res	5,m
key2:	inc	hl
	djnz	key1
	ei
	LD	L,4
	JR	STATS1
; IRM-EBENENWECHSEL
IRMEB:	AND	7		;BIT 0-2
	LD	B,A
	LD	A,0F8H
IRM3:	AND	(IX-32)		;=LATCH 08
	OR	B		;BIT0=ANZEIGE 0/1
	LD	(IX-32),A	;   1=FARBEBENE
	OUT	(84H),A		;   2=ZUGRIFF 0/1
	RET
; IRM-AUFLOESUNG HOCH
IRMAUF:	LD	B,8		;BIT 3
IRM2:	LD	A,0F7H
	JR	IRM3
; IRM-AUFLOESUNG NIEDRIG
IRMAU2:	LD	B,0
	JR	IRM2
;
CLS	EQU	OUT
CUD	EQU	OUT
CUU	EQU	OUT
CUR	EQU	OUT
CUL	EQU	OUT
CLL	EQU	OUT
BEEP	EQU	OUT
CR	EQU	OUT
HOME	EQU	OUT
CLR	EQU	OUT
CES	EQU	CESP
ŠCEL	EQU	CELP

;Unterprogramm	SCROLL
SCR:	LD	(IX+7),184
	LD	IY,BST2
	PUSH	IY
	LD	IY,BST1
SR1:	LD	E,(IY)
	LD	D,(IY+1)
	LD	L,(IY+16)
	LD	H,(IY+17)
	LD	BC,32
	LDIR
	INC	IY
	INC	IY
	EX	(SP),IY
	LD	E,(IY)
	LD	D,(IY+1)
	LD	L,(IY+16)
	LD	H,(IY+17)
	LD	C,8
	LDIR
	INC	IY
	INC	IY
	EX	(SP),IY
	DEC	(IX+7)
	JR	NZ,SR1
	POP	IY
	LD	HL,BST1+368
	LD	C,8
SR2:	LD	E,M
	INC	HL
	LD	D,M
	INC	HL
	LD	B,32
	XOR	A
SR3:	LD	(DE),A
	INC	DE
	DJNZ	SR3
	DEC	C
	JR	NZ,SR2
	LD	HL,BST2+368
	LD	C,8
SR6:	LD	E,M
	INC	HL
	LD	D,M
	INC	HL
	LD	B,8
	XOR	A
SR5:	LD	(DE),A
	INC	DE
	DJNZ	SR5
	DEC	C
	JR	NZ,SR6
	RET
Š;
cucpl:	PUSH	HL
	PUSH	DE
	PUSH	BC
	ld	hl,(curso)
	push	af
	ld	A,(bsmod)
	and	a
	jr	z,cc
	call	caos
	defb	25h		;caos-cursor-kompl.
CUCPOP:	pop	af
	JP	POPS
;
cc:	srl	l
	LD	C,0F0H
	JR	NC,CC2
	LD	C,0FH
CC2:	LD	A,L
	CP	32	;RECHTER TEIL?
	LD	IY,BST1
	JR	C,CC1
	LD	IY,BST2
	LD	A,L
	SUB	32
	LD	L,A
CC1:	LD	E,L
	LD	D,0
	LD	L,H
	LD	H,D
	ADD	HL,HL
	ADD	HL,HL
	ADD	HL,HL
	ADD	HL,HL
	EX	DE,HL
	ADD	IY,DE
	EX	DE,HL
	LD	B,8
	LD	H,0
CC3:	LD	L,(IY)
	INC	IY
	LD	H,(IY)
	INC	IY
Š	ADD	HL,DE
	LD	A,M
	XOR	C
	LD	M,A
	DJNZ	CC3
	JR	CUCPOP
; Ausgabeprogramm fuer Zeichen und Control's
; a = Code
ch5:	ld	e,(hl)
	inc	hl
	ld	d,(hl)
	ex	de,hl
	ld	bc,(curso)
	jp	(hl)
;
char80:	ld	hl,codtab	;suchen controls
	ld	b,12
ch3:	cp	(hl)
	inc	hl
	jr	z,ch5
	inc	hl
	inc	hl
	djnz	ch3
ch4:	and	7fh
	sub	20h
	ret	c	;nicht vorh. controls
	ld	h,0
	ld	l,a
	add	hl,hl
	add	hl,hl
	add	hl,hl
	ld	de,zg
	add	hl,de	;hl-> zg
	ex	de,hl
	ld	bc,(curso)
OUTINC:	ld	hl,bst1
	ld	a,c
	cp	64	;rechte haelfte?		
	jr	c,ch6
	sub	64
	ld	hl,bst2
ch6:	push	hl
	ld	l,b
	ld	h,0
	add	hl,hl
	add	hl,hl
	add	hl,hl
	add	hl,hl	;*8*2
	pop	bc
	add	hl,bc
	rra		;cy -  rechts/links
	ld	c,a
	ld	b,8
ch8:	push	hl
	ld	a,(de)	;aus zg
Š	push	af
	ld	a,(hl)
	inc	hl
	ld	h,(hl)
	or	c
	ld	l,a
	pop	af
	push	af
	ld	a,(hl)
	jr	c,ch7
	and	0fh
	ld	(hl),a
	pop	af
	push	af
	and	0f0h
	jr	ch9
;
ch7:	and	0f0h
	ld	(hl),a
	pop	af
	push	af
	and	0fh
ch9:	or	(hl)
	ld	(hl),a
	inc	de
	pop	af
	pop	hl
	inc	hl
	inc	hl
	djnz	ch8
cur8:	ld	bc,(curso)	
	inc	c
	ld	a,c
	cp	80
	jr	nz,curset
	ld	c,0
lf1:	inc	b
	ld	a,24
	cp	b
	jr	z,ch11
curset:	ld	(curso),bc
scret:	ret
;
ch11:	ld	hl,(scend)
	jp	(hl)
;
scroll:	call	scr		;scroll-mode
	ld	bc,1700h	;Anfang letzte Zeile		
	jr	curset
;
page:	call	cls8		;page-mode
home8:	ld	bc,0		;home-position
	jr	curset
;
del:	call	back8
Š	ld	a,' '
	call	ch4
back8:	ld	bc,(curso)
	dec	c
	ld	a,0ffh
	cp	c
	jr	nz,curset
	ld	c,79
cul1:	ld	a,0ffh
	dec	b
	cp	b
	jr	nz,curset
	INC	B
curs1:	jr	curset
;
cr8:	ld	c,0
	jr	curset
;
screst:	ld	bc,(curso)
	push	bc
	ld	hl,(scend)
	push	hl
	ld	hl,scret
	ld	(scend),hl
	ld	a,80
	sub	c
	ld	h,0
	ld	l,a
	ld	de,80
	ld	a,23
	sub	b
	jr	z,scra1
scr2:	add	hl,de
	dec	a
	jr	nz,scr2
scra1:	ld	c,l
	ld	b,h
scr1:	ld	a,' '
	push	bc
	call	ch4
	pop	bc
	dec	bc
	ld	a,c
	or	b
	jr	nz,scr1
	jr	lr1
;
lnrest:
ln3:	push	bc
	ld	hl,(scend)
	push	hl
	ld	hl,scret
	ld	(scend),hl
	ld	a,80
	sub	c
Š	ld	b,a
lr2:	ld	a,' '
	push	bc
	call	ch4
	pop	bc
	djnz	lr2
lr1:	pop	hl
	ld	(scend),hl
	pop	bc
	jr	curs1
;
clln:	xor	a
	ld	(curso),a
	ld	c,a
	jr	ln3
;
; Zeichenbildtabellen
	.XLIST
zg:	defb	0,0,0,0,0,0,0,0			;space
	defb	22h,22h,22h,22h,22h,0,22h,0	;!
	defb	33h,33h,0,0,0,0,0,0		;"
	defb	0,55h,77h,55h,77h,55h,0,0	;#
	defb	22h,77h,66h,22h,33h,77h,22h,0	;
	defb	0,55h,11h,22h,22h,44h,55h,0	;%
	defb	0,22h,55h,22h,55h,44h,33h,0	;&
	defb	22h,22h,0,0,0,0,0,0		;'
	defb	33h,44h,44h,44h,44h,44h,33h,0	;(
	defb	66h,11h,11h,11h,11h,11h,66h,0 	;)
	defb	0,0,55h,22h,55h,0,0,0		;*
	defb	0,0,22h,77h,22h,0,0,0		;+
	defb	0,0,0,0,0,22h,22h,44h		;,
	defb	0,0,0,77h,0,0,0,0		;-
	defb	0,0,0,0,0,0,22h,0		;.
	defb	11h,11h,22h,22h,22h,44h,44h,0	;/
	defb	22h,55h,55h,55h,55h,55h,22h,0	;0
	defb	11h,33h,55h,11h,11h,11h,11h,0	;1
	defb	22h,55h,55h,11h,22h,44h,77h,0	;2
	defb	22h,55h,11h,22h,11h,55h,22h,0	;3
	defb	55h,55h,55h,77h,11h,11h,11h,0	;4
	defb	77h,44h,44h,77h,11h,55h,22h,0	;5
	defb	22h,44h,44h,66h,55h,55h,22h,0	;6
	defb	77h,11h,11h,11h,22h,22h,22h,0	;7
	defb	22h,55h,55h,22h,55h,55h,22h,0	;8
	defb	22h,55h,55h,33h,11h,11h,22h,0	;9
	defb	0,0,22h,0,0,22h,0,0		;:
	defb	0,0,22h,0,0,22h,22h,44h		;;
	defb	0,11h,22h,44h,22h,11h,0,0	;>
	defb	0,0,77h,0,77h,0,0,0		;=
	defb	0,44h,22h,11h,22h,44h,0,0	;<
	defb	22h,55h,11h,22h,22h,0,22h,0	;?
	defb	66h,55h,11h,22h,55h,55h,33h,0	;@
	defb	22h,55h,55h,77h,55h,55h,55h,0	;A
	defb	66h,55h,55h,66h,55h,55h,66h,0	;B
	defb	22h,55h,44h,44h,44h,55h,22h,0	;C
	defb	66h,55h,55h,55h,55h,55h,66h,0	;D
	defb	77h,44h,44h,66h,44h,44h,77h,0	;E
Š	defb	77h,44h,44h,66h,44h,44h,44h,0	;F
	defb	22h,55h,44h,44h,55h,55h,33h,0	;G
	defb	55h,55h,55h,77h,55h,55h,55h,0	;H
	defb	77h,22h,22h,22h,22h,22h,77h,0	;I
	defb	77h,11h,11h,11h,11h,55h,22h,0	;J
	defb	55h,55h,66h,44h,66h,55h,55h,0	;K
	defb	44h,44h,44h,44h,44h,44h,77h,0	;L
	defb	55h,77h,77h,55h,55h,55h,55h,0	;M
	defb	66h,55h,55h,55h,55h,55h,55h,0	;N
	defb	77h,55h,55h,55h,55h,55h,77h,0	;O
	defb	66h,55h,55h,66h,44h,44h,44h,0	;P
	defb	77h,55h,55h,55h,55h,77h,77h,11h	;Q
	defb	66h,55h,55h,66h,55h,55h,55h,0	;R
	defb	22h,55h,44h,22h,11h,55h,22h,0	;S
	defb	77h,22h,22h,22h,22h,22h,22h,0	;T
	defb	55h,55h,55h,55h,55h,55h,77h,0	;U
	defb	55h,55h,55h,55h,55h,55h,22h,0	;V
	defb	55h,55h,55h,55h,77h,77h,55h,0	;W
	defb	55h,55h,55h,22h,55h,55h,55h,0	;X
	defb	55h,55h,55h,77h,22h,22h,22h,0	;Y
	defb	77h,11h,11h,22h,44h,44h,77h,0	;Z
zw1:	defb	77h,44h,44h,44h,44h,44h,77h,0	;[
	defb	44h,44h,22h,22h,22h,11h,11h,0	;\
	defb	77h,11h,11h,11h,11h,11h,77h,0	;]
	defb	00h,22h,55h,0,0,0,0,0		;^
	defb	0,0,0,0,0,0,0,77h		;_
; Kleinbuchstaben
	defb	66h,11h,22h,55h,22h,44h,33h,0	;60h
	defb	0,0,22h,55h,55h,55h,33h,0	;a
	defb	44h,44h,66h,55h,55h,55h,66h,0	;b
	defb	0,0,33h,44h,44h,44h,33h,0	;c
	defb	11h,11h,33h,55h,55h,55h,33h,0	;d
	defb	0,0,22h,55h,77h,44h,77h,0	;e
	defb	22h,55h,44h,66h,44h,44h,44h,44h	;f
	defb	0,0,33h,55h,55h,33h,11h,66h	;g
	defb	44h,44h,66h,55h,55h,55h,55h,0	;h
	defb	0,22h,0,22h,22h,22h,22h,0	;i
	defb	0,22h,0,22h,22h,22h,22h,66h	;j
	defb	44h,44h,55h,55h,66h,55h,55h,0	;k
	defb	44h,44h,44h,44h,44h,55h,22h,0	;l
	defb	0,0,55h,77h,55h,55h,55h,0	;m
	defb	0,0,22h,55h,55h,55h,55h,0	;n
	defb	0,0,22h,55h,55h,55h,22h,0	;o
	defb	0,0,22h,55h,55h,66h,44h,44h	;p
	defb	0,0,22h,55h,55h,33h,11h,11h	;q
	defb	0,0,66h,55h,44h,44h,44h,0	;r
	defb	0,0,33,44h,22h,11h,66h,0	;s
	defb	22h,22h,77h,22h,22h,22h,11h,0	;t
	defb	0,0,55h,55h,55h,55h,77h,0	;u
	defb	0,0,55h,55h,55h,55h,22h,0	;v
	defb	0,0,55h,55h,77h,77h,55h,0	;w
	defb	0,0,55h,55h,22h,55h,55h,0	;x
	defb	0,0,55h,55h,55h,33h,11h,77h	;y
	defb	0,0,77h,11h,22h,44h,77h,0	;z
zw2:	defb	33h,22h,22h,44h,22h,22h,33h,0	;{
Š	defb	22h,22h,22h,22h,22h,22h,22h,0	;|
	defb	66h,22h,22h,11h,22h,22h,66h,0	;}
	defb	77h,0,0,0,0,0,0,0		;~
	defb	77h,77h,77h,77h,77h,77h,77h,77h	;del
; umlaute optional
gum:	defb	55h,22h,55h,55h,77h,55h,55h,0	;AE
	defb	55h,0,77h,55h,55h,55h,77h,0	;OE
	defb	55h,0,55h,55h,55h,55h,77h,0	;UE
kum:	defb	00,55h,0,22h,55h,55h,33h,0	;ae
	defb	0,55h,0,22h,55h,55h,22h,0	;oe
	defb	0,55h,0,55h,55h,55h,77h,0	;ue
	defb	22h,55h,55h,66h,55h,55h,66h,44h	;sz
	.LIST	
;Code-tabelle fuer steuerzeichen
codtab:	defb	1		;^A
	defw	home8
	defb	7		;^G
	defw	beep
	defb	8		;^H
	defw	back8
	defb	0ah		;^J
	defw	lf1
	defb	0ch		;^L
	defw	page
	defb	0dh		;^M
	defw	cr8
	defb	14h		;^T
	defw	screst
	defb	15h		;^U
	defw	cur8
	defb	16h		;^V
	defw	lnrest
	defb	18h		;^X
	defw	clln
	defb	1ah		;^Z
	defw	cul1	
	defb	7fh		;DEL
	defw	del
;
;merkzellen
escmer:	defb	0
escad:	defw	ret
pzeig:	defw	ppuf	
scend:	defw	scroll
CURMER:	DEFB	0
BSMOD:	DEFb	0
scmode:	defb	0
KC4:	DEFB	0
;PARAMETERPUFFER
PPUF:	DEFW	0
	DEFW	0
	DEFW	0
	DEFW	0
;ESCAPE-FOLGENTABELLE
;A=41H=65 - PUNKTSETZEN
ESCTAB:	defb	3	;parameter
	DEFW	PSET	;XX,Y
;B=42H=66 - PUNKTLOESCHEN
	defb	3
	DEFW	PRES	;XX,Y
;C=43H=67 - GRAFIKFARBE
	defb	1
	DEFW	GFARB	;F
;D=44H=68 - LINIE
	defb	6
	DEFW	LINE	;XX1,Y1,XX2,Y2
;E=45H=69 - KREIS
	defb	4
	DEFW	CIRCL	;XX,Y,R
;F=46H=70 - FENSTERAUFRUF
	defb	1
	DEFW	WINDOW	;N
;G=47H=71 - TONAUSGABE
	defb	6
	DEFW	SOUND	;T1,V1,T2,V2,L,Z
;H=48H=72 - TEXTFARBE
	defb	2
	DEFW	COLORZ	;V,H
;I=49H=73 - TASTATURSTATUS
	defb	0
Š	DEFW	ret	;-
;J=4AH=74 - TASTENKODE ABHOLEN
	defb	0
	DEFW	ret	;-
;K=4BH=75 - ZEILENEINGABE
	defb	0
	DEFW	ret	;-
;L=4CH=76 - FENSTER INITIALISIEREN
	defb	5
	DEFW	WININ	;N,X1,Y1,X2,Y2
;M=4DH=77 - GRAFIKSCHIRM LOESCHEN
	defb	0
	DEFW	CLSG	;- GRAFIK-CLS
;N=4EH=78 - VORDERGRUND WECHSELN
	defb	1
	DEFW	INK	;F-WECHSELN
;O=4FH=79 - HINTERGRUND WECHSELN
	defb	1
	DEFW	BACK	;H-    "
;P=50H=80 - BILDSCHIRMMODE WECHSELN
	defb	0
	DEFW	BSMODE	;-
;Q=51H=81 - 1 BYTE LESEN
	defb	2
	DEFW	read1	;XX
;R=52H=82 - 256 BYTES LESEN
	defb	2
	DEFW	readn	;XX
;S=53H=83 - 1 BYTE SCHREIBEN
	defb	3
	DEFW	WRITE1	;XX,A
;T=54H=84 - NN BYTES SCHREIBEN
	defb	5
	DEFW	writen	;xx,nn,a
;U=55H=85 - UNTERPROGRAMM AUFRUFEN
	defb	2
	DEFW	GOSUB	;XX
;V=56H=86 - DIREKTAUSGABE ZEICHENCODE
	defb	1
	DEFW	CAOSBS	;Z
;W=57H=87 - AUSGABE USERPORT1
	defb	1
	DEFW	USOUT2	;Z
;X=58H=88 - ausgabe userport2
	defb	1
	DEFW	usout3	;-
;Y=59H=89 - EINLESEN USERPORT
	defb	0
	DEFW	ret	;Z
;Z=5AH=90 -
	defb	0
	DEFW	RET	;-
;[=5BH=91 - AUFRUF CAOS-SPRUNGVERTEILER
	defb	1
	DEFW	CAOSPV	;N
Š;\=5CH=92 - RUECKKEHR INS CAOS
	defb	0
	DEFW	EXIT	;-
;]=5DH=93 - Wechsel Zeichensatz
	defb	0
	DEFW	zsatz
;^=5EH=94 - Wechsel page/scroll
	defb	0
	DEFW	scrmod
;~=5FH=95 - Wechsel keybord gross/klein
	defb	0
	defw	kbdmod
;`=60H=96 - Wechsel IRM-Ebene
	DEFB	1	;STEUERBYTE
	DEFW	IRMEB
;a=61H=97 - IRM-Aufloesung hoch
	DEFB	0
	DEFW	IRMAUF
;b=62H=98 - IRM-Aufloesung niedrig
	DEFB	0
	DEFW	IRMAU2   
	.PRINTX	'ENDE BILDSCHIRMAUSGABE'