title INITIALISIERUNG EINES KOPPLUNGSTREIBERS
;
; LADEN EINES TREIBERS  *.KOP 
; UEBERTRAGEN UND INITIALISIEREN IM KC
;
.Z80
FCB	EQU	5CH
DMA	EQU	80H
ESC	EQU	1BH
;
START:	LD	HL,(1) 	;WARMSTART
	LD	DE,9
	ADD	HL,DE
	LD	(CALAD+1),HL	
	LD	HL,LSTTXT
	LD	BC,3
	LD	DE,FCB+9
	LDIR		;TYP KOP
	LD	C,15	;OPEN
	LD	DE,FCB
	CALL	5
	INC	A
	JP	Z,S7
	XOR	A	;cr=0
	LD	(FCB+32),A
	LD	HL,PUFFER
S1:	LD	C,20	;SEQU. LESEN
	LD	DE,FCB
	PUSH	HL
	CALL	5
	POP	HL
	LD	DE,DMA
	EX	DE,HL
	LD	BC,128
	LDIR
S20:			;HL= ENDE	
	LD	A,ESC
	CALL	OUT
	LD	A,'T'   ;UEBETRAGUNG in KC
	CALL	OUT
	LD	A,080H	;ADRESSE LOW
	CALL	OUT
	LD	A,3	;        HIGH
	CALL	OUT
	LD	DE,PUFFER
	LD	HL,80H
	LD	A,L
	CALL	OUT	;LAENGE LOW
	LD	A,H
	CALL	OUT	;       HIGH
SL:	LD	A,(DE)
	CALL	OUT
	DEC	HL
	INC	DE
	LD	A,L
	OR	H
	JR	NZ,SL
	LD	A,ESC
	CALL	OUT
	LD	A,'U'	;CALL im KC
	CALL	OUT
	LD	A,080H	;ADRESSE LOW
	CALL	OUT
	LD	A,3	;        HIGH
	CALL	OUT
	LD	A,0AH
	CALL	OUT
	LD	A,0DH
	CALL	OUT
WARM:	JP	0	;WARMSTART
;
OUT:	PUSH	HL
	PUSH	DE
	PUSH	BC
	LD	C,A
CALAD:	CALL	0
	POP	BC
	POP	DE
	POP	HL
	RET
S7:	LD	DE,TX2
	LD	C,9	
	CALL	5
	JR	WARM
;
;
LSTTXT:	DEFM 	'KOP'
	DEFM	'$'
TX2:	DEFM	' Datei nicht gefunden !'
	DEFW	0A0DH
	DEFM	'$'
PUFFER	EQU	$	;INCLUDE FILE
	END	START