.Z80
;INSTALLATIONSTREIBER FUER S 3004
;26.08.88
	.PHASE	0BA00H
;VEREINBARUNGEN:
CAOS	EQU	0F003H
MODU	EQU	26H		;UP NR.CAOS
PUFAD	EQU	0B700H
;SYSTEMZELLEN CAOS
HCADR	EQU	0B799H		;HARD-COPY-ADRESSE
;
MKENN	EQU	0EEH
SIO	EQU	08H
SIOB	EQU	SIO+1
CTC	EQU	0CH
INITL:	JR	START	;AUFRUF INITIALISIERUNG
OUTLST:	JR	SD1	;BYTEAUSGABE
;
INTAB:	DEFB	47H	;BETRIEBSART CTC
	DEFB	5BH	;ZEITKONST.CTC
INTABS:	DEFB	18H
	DEFB	4	;->WR4
	DEFB	4	;9600 BAUD
	DEFB	3	;->WR3
	DEFB	20H
	DEFB	5	;->WR5
	DEFB	6AH
;DRUCKEREINSTELLUNGEN
INTABE:	DEFB	0DH	;CR
	DEFB	0AH	;LF
TABEND	EQU	$
;
	DEFW	7F7FH
	DEFM	'S3004'
	DEFB	1
START:	LD	BC,880H
NEXT:	IN	A,(C)
	CP	0EEH	;V24-MODUL ?
	JR	Z,FOUND
	INC	B
	JR	NZ,NEXT
	RET
;
FOUND:	LD	L,B
	LD	A,2
	LD	D,1
	LD	E,D
	CALL	CAOS
	DEFB	MODU
;IN HARDCOPY EINTRAGEN
	LD	HL,BIMOD
	LD	(HCADR),HL
	LD	C,CTC
	LD	B,INTABS-INTAB	;COUNTER
	LD	HL,INTAB
	DI
	OTIR
;INIT SIO
	LD	C,SIO+2
	LD	B,INTABE-INTABS
	OTIR
	EI
	IN	A,(SIO+2)	;CONTROL
	BIT	5,A		;CTS ?
	RET	Z		;ABBRUCH NOT READY
	LD	HL,INTABE
	LD	B,TABEND-INTABE
INBIM:	LD	A,(HL)	;ZEIGER TABELLE
	INC	HL
	CALL	SD1
	DJNZ	INBIM
	RET
;
;***************************************
; ZEICHENAUSGABE ZEICHEN IN A
SD1:	PUSH	AF
SD6:	IN	A,(SIO+2)
	BIT	2,A
	JR	Z,SD6
SD5:	POP	AF
	OUT	(SIO),A
	AND	A		
	RET
;	
BIMOD:	RET
;***************************************
	DEFM	'260888'
	.DEPHASE
	END